home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 6.st / GFAGDOS.ARC / GDOSPROC.LST < prev    next >
Encoding:
File List  |  1989-10-19  |  13.7 KB  |  648 lines
  1. '
  2. '               GEM GRAPHIC PROCEDURES FOR GDOS
  3. '                         by Jim Burton
  4. '               COPYRIGHT 1990 ANTIC PUBLISHING
  5. '
  6. '                    CONTROL FUNCTIONS
  7. '
  8. Procedure Openwork(Device%)
  9.   '
  10.   ' Opens the device workstation for output.
  11.   '
  12.   Dpoke Contrl+2,0
  13.   Dpoke Contrl+6,11
  14.   Dpoke Intin,Device%
  15.   Dpoke Intin+20,2
  16.   Vdisys 1
  17.   Handle%=Dpeek(Contrl+12)   ! the device's handle
  18.   If Handle%=0
  19.     Alert 1,"GDOS not responding.|Aborting",1,"OK",Dummy%
  20.     End
  21.   Endif
  22.   Devicewidth%=Dpeek(Intout)
  23.   Deviceheight%=Dpeek(Intout+2)
  24. Return
  25. '
  26. Procedure Printwork(Handle%)
  27.   '
  28.   ' Causes the graphics subroutines performed on the workstation
  29.   ' to be printed out.
  30.   '
  31.   Dpoke Contrl+12,Handle%
  32.   Vdisys 4
  33. Return
  34. '
  35. Procedure Closework(Handle%)
  36.   '
  37.   ' Closes the workstation.
  38.   '
  39.   Dpoke Contrl+12,Handle%
  40.   Vdisys 2
  41. Return
  42. '
  43. Procedure Loadfont(Handle%,Select%)
  44.   '
  45.   ' Loads the fonts listed in ASSIGN.SYS after the printer driver file.
  46.   '
  47.   Dpoke Contrl+2,0
  48.   Dpoke Contrl+6,1
  49.   Dpoke Contrl+12,Handle%
  50.   Dpoke Intin,Select%
  51.   Vdisys 119
  52. Return
  53. '
  54. Procedure Unloadfont(Handle%,Select%)
  55.   '
  56.   ' Frees the memory taken by the fonts.
  57.   '
  58.   Dpoke Contrl+2,0
  59.   Dpoke Contrl+6,1
  60.   Dpoke Contrl+12,Handle%
  61.   Dpoke Intin,Select%
  62.   Vdisys 120
  63. Return
  64. '
  65. Procedure Clip(Handle%,Flag%,X1%,Y1%,X2%,Y2%)
  66.   '
  67.   ' Confines the following graphic output to the points within the
  68.   ' rectangle described by X1%,Y1% to X2%,Y2%.
  69.   ' Flag% determines if the clipping is on or off.
  70.   ' (0 is off, 1 is on)
  71.   '
  72.   Dpoke Contrl+2,2
  73.   Dpoke Contrl+6,1
  74.   Dpoke Contrl+12,Handle%
  75.   Dpoke Intin,Flag%
  76.   Dpoke Ptsin,X1%
  77.   Dpoke Ptsin+2,Y1%
  78.   Dpoke Ptsin+4,X2%
  79.   Dpoke Ptsin+6,Y2%
  80.   Vdisys 129
  81. Return
  82. '
  83. Procedure Newpage(Handle%)
  84.   '
  85.   ' For the printer, causes a form-feed.
  86.   '
  87.   Dpoke Contrl+12,Handle%
  88.   Vdisys 3
  89. Return
  90. '
  91. '                    ATTRIBUTE FUNCTIONS
  92. '
  93. Procedure Set_writemode(Handle%,Mode%)
  94.   '
  95.   ' Sets the writing mode.
  96.   ' If Mode% = 1   Replace mode (normal)
  97.   ' If Mode% = 2   Transparent
  98.   ' If mode% = 3   Exclusive-Or
  99.   ' If mode% = 4   Reverse Transparent
  100.   '
  101.   ' NOTE:  See BASIC's  GRAPHMODE  command
  102.   '
  103.   Dpoke Contrl+2,0
  104.   Dpoke Contrl+6,1
  105.   Dpoke Contrl+12,Handle%
  106.   Dpoke Intin,Mode%
  107.   Vdisys 32
  108. Return
  109. '
  110. Procedure Set_fillcol(Handle%,Col%)
  111.   '
  112.   ' Sets the fill color.  (for printers, 1 or 0)
  113.   '
  114.   Dpoke Contrl+2,0
  115.   Dpoke Contrl+6,1
  116.   Dpoke Contrl+12,Handle%
  117.   Dpoke Intin,Col%
  118.   Vdisys 25
  119. Return
  120. '
  121. Procedure Set_fillbord(Handle%,Flag%)
  122.   '
  123.   ' Flag% determines if the filled object's border is shown.
  124.   ' If Flag% = 0   the border is not shown.
  125.   ' If Flag% = 1   the border is shown.
  126.   '
  127.   Dpoke Contrl+2,0
  128.   Dpoke Contrl+6,1
  129.   Dpoke Contrl+12,Handle%
  130.   Dpoke Intin,Flag%
  131.   Vdisys 104
  132. Return
  133. '
  134. Procedure Set_fillstyle(Handle%,Style%)
  135.   '
  136.   ' Sets the fill pattern style.
  137.   '
  138.   ' NOTE:  See BASIC's  DEFFILL  command
  139.   ' (If style%=4, the user-defined pattern is selected. See Set_userfill.)
  140.   '
  141.   Dpoke Contrl+2,0
  142.   Dpoke Contrl+6,1
  143.   Dpoke Contrl+12,Handle%
  144.   Dpoke Intin,Style%
  145.   Vdisys 23
  146. Return
  147. '
  148. Procedure Set_fillindex(Handle%,Index%)
  149.   '
  150.   ' Sets the fill pattern.
  151.   '
  152.   ' NOTE:  See BASIC's  DEFFILL  command
  153.   '
  154.   Dpoke Contrl+2,0
  155.   Dpoke Contrl+6,1
  156.   Dpoke Contrl+12,Handle%
  157.   Dpoke Intin,Index%
  158.   Vdisys 24
  159. Return
  160. '
  161. Procedure Set_linecol(Handle%,Col%)
  162.   '
  163.   ' Sets the polyline line color. (for printers, 1 or 0)
  164.   '
  165.   Dpoke Contrl+2,0
  166.   Dpoke Contrl+6,1
  167.   Dpoke Contrl+12,Handle%
  168.   Dpoke Intin,Col%
  169.   Vdisys 17
  170. Return
  171. '
  172. Procedure Set_linetype(Handle%,Type%)
  173.   '
  174.   ' Sets the polyline type.
  175.   '
  176.   ' If Type% = 0  Line is blank.
  177.   ' If Type% = 1  ------------------------------------------------
  178.   ' If Type% = 2  ------------    ------------    ------------
  179.   ' If Type% = 3  ---     ---     ---     ---     ---     ---
  180.   ' If Type% = 4  -------   ---   -------   ---   -------   ---
  181.   ' If Type% = 5  --------        --------        --------
  182.   ' If Type% = 6  ----   --  --   ----   --  --   ----   --  --
  183.   ' If Type% = 7  Use user-defined line.
  184.   '
  185.   Dpoke Contrl+2,0
  186.   Dpoke Contrl+6,1
  187.   Dpoke Contrl+12,Handle%
  188.   Dpoke Intin,Type%
  189.   Vdisys 15
  190. Return
  191. '
  192. Procedure Set_linewid(Handle%,Width%)
  193.   '
  194.   ' Sets the polyline's width.
  195.   ' (Width% can be from 1 to 39, odd numbers only)
  196.   '
  197.   Dpoke Contrl+2,1
  198.   Dpoke Contrl+6,0
  199.   Dpoke Contrl+12,Handle%
  200.   Dpoke Ptsin,Width%
  201.   Dpoke Ptsin+2,0
  202.   Vdisys 16
  203. Return
  204. '
  205. Procedure Set_charabs(Handle%,Height%)
  206.   '
  207.   ' Sets the absolute height of the characters.
  208.   ' (This doesn't seem to work with GDOS v1.2. It may work with later versions.)
  209.   '
  210.   Dpoke Contrl+2,1
  211.   Dpoke Contrl+6,0
  212.   Dpoke Contrl+12,Handle%
  213.   Dpoke Ptsin,0
  214.   Dpoke Ptsin+2,Height%
  215.   Vdisys 12
  216. Return
  217. '
  218. Procedure Set_charpoint(Handle%,Height%)
  219.   '
  220.   ' Sets the height of the characters in points (1/72 inch).
  221.   ' (This doesn't seem to work with GDOS v1.2. It may work with later versions.)
  222.   '
  223.   Dpoke Contrl+2,0
  224.   Dpoke Contrl+6,1
  225.   Dpoke Contrl+12,Handle%
  226.   Dpoke Intin,Height%
  227.   Vdisys 107
  228. Return
  229. '
  230. Procedure Set_charvector(Handle%,Angle%)
  231.   '
  232.   ' Sets the baseline angle of the text.
  233.   ' Angle% is in degrees * 10 (3600 = 360 degrees)
  234.   '
  235.   Dpoke Contrl+2,0
  236.   Dpoke Contrl+6,1
  237.   Dpoke Contrl+12,Handle%
  238.   Dpoke Intin,Angle%
  239.   Vdisys 13
  240. Return
  241. '
  242. Procedure Set_font(Handle%,Font%)
  243.   '
  244.   ' Sets the font to be printed.
  245.   ' (Again, this doesn't seem to work properly with GDOS 1.2)
  246.   '
  247.   Dpoke Contrl+2,0
  248.   Dpoke Contrl+6,1
  249.   Dpoke Contrl+12,Handle%
  250.   Dpoke Intin,Font%
  251.   Vdisys 21
  252. Return
  253. '
  254. Procedure Set_charcol(Handle%,Col%)
  255.   '
  256.   ' Sets the color of the text to be printed.
  257.   ' (For printers, 0 or 1)
  258.   '
  259.   Dpoke Contrl+2,0
  260.   Dpoke Contrl+6,1
  261.   Dpoke Contrl+12,Handle%
  262.   Dpoke Intin,Col%
  263.   Vdisys 22
  264. Return
  265. '
  266. Procedure Set_textalign(Handle%,Horz%,Vert%)
  267.   '
  268.   ' Sets the text alignment.
  269.   ' Horz% = 0  left
  270.   '       = 1  centered
  271.   '       = 2  right
  272.   '
  273.   ' Vert% = 0  baseline
  274.   '       = 1  half line
  275.   '       = 2  ascent line
  276.   '       = 3  bottom line
  277.   '       = 4  descent line
  278.   '       = 5  top line
  279.   '
  280.   Dpoke Contrl+2,0
  281.   Dpoke Contrl+6,2
  282.   Dpoke Contrl+12,Handle%
  283.   Dpoke Intin,Horz%
  284.   Dpoke Intin+2,Vert%
  285.   Vdisys 39
  286. Return
  287. '
  288. Procedure Set_chareffect(Handle%,Effect%)
  289.   '
  290.   ' Sets the special effect to be used while printing.
  291.   '
  292.   ' NOTE:  See BASIC's  DEFTEXT  command
  293.   '
  294.   Dpoke Contrl+2,0
  295.   Dpoke Contrl+6,1
  296.   Dpoke Contrl+12,Handle%
  297.   Dpoke Intin,Effect%
  298.   Vdisys 106
  299. Return
  300. '
  301. Procedure Set_userline(Handle%,Pattern%)
  302.   '
  303.   ' Sets a user-defined line pattern.
  304.   ' Pattern% is a 2-byte bit map of the line.
  305.   '
  306.   Dpoke Contrl+2,0
  307.   Dpoke Contrl+6,1
  308.   Dpoke Contrl+12,Handle%
  309.   Dpoke Intin,Pattern%
  310.   Vdisys 113
  311. Return
  312. '
  313. Procedure Set_endstyle(Handle%,Begin%,End%)
  314.   '
  315.   ' Sets the begining and ending polyline styles.
  316.   '
  317.   ' Begin% or End% can contain the following values:
  318.   ' 0 = square.
  319.   ' 1 = arrow.
  320.   ' 2 = round.
  321.   '
  322.   Dpoke Contrl+2,0
  323.   Dpoke Contrl+6,2
  324.   Dpoke Contrl+12,Handle%
  325.   Dpoke Intin,Begin%
  326.   Dpoke Intin+2,End%
  327.   Vdisys 108
  328. Return
  329. '
  330. Procedure Set_polymark(Handle%,Symbol%)
  331.   '
  332.   ' Sets the polymarker style.
  333.   '
  334.   ' Symbol% can contain the following values:
  335.   ' 1 = point.
  336.   ' 2 = plus sign.
  337.   ' 3 = star.
  338.   ' 4 = square.
  339.   ' 5 = diagonal cross.
  340.   ' 6 = diamond.
  341.   '
  342.   Dpoke Contrl+2,0
  343.   Dpoke Contrl+6,1
  344.   Dpoke Contrl+12,Handle%
  345.   Dpoke Intin,Symbol%
  346.   Vdisys 18
  347. Return
  348. '
  349. Procedure Set_polyheight(Handle%,Height%)
  350.   '
  351.   ' Sets the polymarker height.
  352.   '
  353.   Dpoke Contrl+2,1
  354.   Dpoke Contrl+6,0
  355.   Dpoke Contrl+12,Handle%
  356.   Dpoke Ptsin,0
  357.   Dpoke Ptsin+2,Height%
  358.   Vdisys 19
  359. Return
  360. '
  361. Procedure Set_markcol(Handle%,Col%)
  362.   '
  363.   ' Sets the polymarker color.
  364.   ' (For printers, 0 or 1)
  365.   '
  366.   Dpoke Contrl+2,0
  367.   Dpoke Contrl+6,1
  368.   Dpoke Contrl+12,Handle%
  369.   Dpoke Intin,Col%
  370.   Vdisys 20
  371. Return
  372. '
  373. Procedure Set_userfill(Handle%,Loc%)
  374.   '
  375.   ' Sets the user-defined fill pattern.
  376.   ' Loc% points to a 32-byte string which
  377.   ' contains the bit-image data.
  378.   '
  379.   Dpoke Contrl+2,0
  380.   Dpoke Contrl+6,16
  381.   Dpoke Contrl+12,Handle%
  382.   Bmove Loc%,Intin,32
  383.   Vdisys 112
  384. Return
  385. '
  386. '                    GRAPHIC FUNCTIONS
  387. '
  388. Procedure Fillpoly(Handle%,Top%)
  389.   '
  390.   ' Draws a filled-in polyline.
  391.   '
  392.   ' NOTE:
  393.   ' Before calling this procedure, you must define an array
  394.   ' Tempx%() containing all of the X coordinates in the polyline.
  395.   ' (no more than 126 coordinates are allowed)
  396.   ' You must do the same for the Y coordinates in Tempy%().
  397.   ' Top% is the number of coordinate pairs.
  398.   '
  399.   Dpoke Contrl+2,Top%+1   !  number of points in polyline
  400.   Dpoke Contrl+6,0
  401.   Dpoke Contrl+12,Handle%
  402.   For K%=0 To Top%
  403.     Dpoke Ptsin+(K%*4),Tempx%(K%)
  404.     Dpoke Ptsin+(K%*4)+2,Tempy%(K%)
  405.   Next K%
  406.   Vdisys 9
  407. Return
  408. '
  409. Procedure Drawpoly(Handle%,Top%)
  410.   '
  411.   ' Draws a polyline.
  412.   '
  413.   ' NOTE:  See procedure FILLPOLY above.
  414.   '
  415.   Dpoke Contrl+2,Top%+1   !  number of points in the polyline
  416.   Dpoke Contrl+6,0
  417.   Dpoke Contrl+12,Handle%
  418.   For K%=0 To Top%
  419.     Dpoke Ptsin+(K%*4),Tempx%(K%)
  420.     Dpoke Ptsin+(K%*4)+2,Tempy%(K%)
  421.   Next K%
  422.   Vdisys 6
  423. Return
  424. '
  425. Procedure Markpoly(Handle%,Top%)
  426.   '
  427.   ' Draws endpoints of a polyline.
  428.   '
  429.   ' NOTE:  See procedure FILLPOLY above.
  430.   '
  431.   Dpoke Contrl+2,Top%+1   !  number of points in the polyline
  432.   Dpoke Contrl+6,0
  433.   Dpoke Contrl+12,Handle%
  434.   For K%=0 To Top%
  435.     Dpoke Ptsin+(K%*4),Tempx%(K%)
  436.     Dpoke Ptsin+(K%*4)+2,Tempy%(K%)
  437.   Next K%
  438.   Vdisys 7
  439. Return
  440. '
  441. Procedure Drawcircle(Handle%,Cx%,Cy%,Rad%)
  442.   '
  443.   ' Draws a circle.
  444.   '
  445.   Dpoke Contrl+2,3
  446.   Dpoke Contrl+6,0
  447.   Dpoke Contrl+10,4
  448.   Dpoke Contrl+12,Handle%
  449.   Dpoke Ptsin,Cx%
  450.   Dpoke Ptsin+2,Cy%
  451.   Dpoke Ptsin+8,Rad%
  452.   Vdisys 11
  453. Return
  454. '
  455. Procedure Drawarc(Handle%,Cx%,Cy%,Rad%,Ba%,Ea%)
  456.   '
  457.   ' Draws an arc.
  458.   ' Ba% and Ea% are the beginning and ending angles of the arc
  459.   ' in degrees times 10.  (360 degrees = 3600)
  460.   '
  461.   Dpoke Contrl+2,4
  462.   Dpoke Contrl+6,2
  463.   Dpoke Contrl+10,2
  464.   Dpoke Contrl+12,Handle%
  465.   Dpoke Intin,Ba%
  466.   Dpoke Intin+2,Ea%
  467.   Dpoke Ptsin,Cx%
  468.   Dpoke Ptsin+2,Cy%
  469.   Dpoke Ptsin+12,Rad%
  470.   Vdisys 11
  471. Return
  472. '
  473. Procedure Drawpie(Handle%,Cx%,Cy%,Rad%,Ba%,Ea%)
  474.   '
  475.   ' Draws a piece of pie, like a pie chart.
  476.   '
  477.   Dpoke Contrl+2,4
  478.   Dpoke Contrl+6,2
  479.   Dpoke Contrl+10,3
  480.   Dpoke Contrl+12,Handle%
  481.   Dpoke Intin,Ba%
  482.   Dpoke Intin+2,Ea%
  483.   Dpoke Ptsin,Cx%
  484.   Dpoke Ptsin+2,Cy%
  485.   Dpoke Ptsin+12,Rad%
  486.   Vdisys 11
  487. Return
  488. '
  489. Procedure Drawellarc(Handle%,Cx%,Cy%,Xrad%,Yrad%,Ba%,Ea%)
  490.   '
  491.   ' Draws an elliptical arc.
  492.   ' Xrad% and Yrad% are the X radius and the Y radius of the arc.
  493.   '
  494.   Dpoke Contrl+2,2
  495.   Dpoke Contrl+6,2
  496.   Dpoke Contrl+10,6
  497.   Dpoke Contrl+12,Handle%
  498.   Dpoke Intin,Ba%
  499.   Dpoke Intin+2,Ea%
  500.   Dpoke Ptsin,Cx%
  501.   Dpoke Ptsin+2,Cy%
  502.   Dpoke Ptsin+4,Xrad%
  503.   Dpoke Ptsin+6,Yrad%
  504.   Vdisys 11
  505. Return
  506. '
  507. Procedure Drawellpie(Handle%,Cx%,Cy%,Xrad%,Yrad%,Ba%,Ea%)
  508.   '
  509.   ' Draws an elliptical pie.
  510.   '
  511.   Dpoke Contrl+2,2
  512.   Dpoke Contrl+6,2
  513.   Dpoke Contrl+10,7
  514.   Dpoke Contrl+12,Handle%
  515.   Dpoke Intin,Ba%
  516.   Dpoke Intin+2,Ea%
  517.   Dpoke Ptsin,Cx%
  518.   Dpoke Ptsin+2,Cy%
  519.   Dpoke Ptsin+4,Xrad%
  520.   Dpoke Ptsin+6,Yrad%
  521.   Vdisys 11
  522. Return
  523. '
  524. Procedure Drawellipse(Handle%,Cx%,Cy%,Xrad%,Yrad%)
  525.   '
  526.   ' Draws an ellipse.
  527.   '
  528.   Dpoke Contrl+2,2
  529.   Dpoke Contrl+6,0
  530.   Dpoke Contrl+10,5
  531.   Dpoke Contrl+12,Handle%
  532.   Dpoke Ptsin,Cx%
  533.   Dpoke Ptsin+2,Cy%
  534.   Dpoke Ptsin+4,Xrad%
  535.   Dpoke Ptsin+6,Yrad%
  536.   Vdisys 11
  537. Return
  538. '
  539. Procedure Drawroundrect(Handle%,X1%,Y1%,X2%,Y2%)
  540.   '
  541.   ' Draws a rectangle with rounded corners.
  542.   '
  543.   Dpoke Contrl+2,2
  544.   Dpoke Contrl+6,0
  545.   Dpoke Contrl+10,8
  546.   Dpoke Contrl+12,Handle%
  547.   Dpoke Ptsin,X1%
  548.   Dpoke Ptsin+2,Y1%
  549.   Dpoke Ptsin+4,X2%
  550.   Dpoke Ptsin+6,Y2%
  551.   Vdisys 11
  552. Return
  553. '
  554. Procedure Fillroundrect(Handle%,X1%,Y1%,X2%,Y2%)
  555.   '
  556.   ' Draws a filled rectangle with rounded corners.
  557.   '
  558.   Dpoke Contrl+2,2
  559.   Dpoke Contrl+6,0
  560.   Dpoke Contrl+10,9
  561.   Dpoke Contrl+12,Handle%
  562.   Dpoke Ptsin,X1%
  563.   Dpoke Ptsin+2,Y1%
  564.   Dpoke Ptsin+4,X2%
  565.   Dpoke Ptsin+6,Y2%
  566.   Vdisys 11
  567. Return
  568. '
  569. Procedure Fillrect(Handle%,X1%,Y1%,X2%,Y2%)
  570.   '
  571.   ' Draws a filled rectangle.
  572.   '
  573.   Dpoke Contrl+2,2
  574.   Dpoke Contrl+6,0
  575.   Dpoke Contrl+12,Handle%
  576.   Dpoke Ptsin,X1%
  577.   Dpoke Ptsin+2,Y1%
  578.   Dpoke Ptsin+4,X2%
  579.   Dpoke Ptsin+6,Y2%
  580.   Vdisys 114
  581. Return
  582. '
  583. Procedure Drawfill(Handle%,X%,Y%,Index%)
  584.   '
  585.   ' Performs a contour fill, which starts at X%,Y% and stops when
  586.   ' the color Index% is reached.
  587.   '
  588.   Dpoke Contrl+2,1
  589.   Dpoke Contrl+6,1
  590.   Dpoke Contrl+12,Handle%
  591.   Dpoke Intin,Index%
  592.   Dpoke Ptsin,X%
  593.   Dpoke Ptsin+2,Y%
  594.   Vdisys 103
  595. Return
  596. '
  597. Procedure Justtext(Handle%,X%,Y%,Loc%,Length%,Word%,Char%)
  598.   '
  599.   ' Prints justified text at coordinates X%,Y%
  600.   '
  601.   ' Length% is the number of pixels the text should extend.
  602.   ' If Word% is set to 1, the space between words is adjusted so
  603.   ' that the text is justified.
  604.   ' If Char% is set to 1, the space between characters is adjusted.
  605.   ' Loc% points to the text string.
  606.   '
  607.   Dpoke Contrl+2,2
  608.   Dpoke Ptsin,X%
  609.   Dpoke Ptsin+2,Y%
  610.   Dpoke Ptsin+4,Length%
  611.   Kount%=0
  612.   Stringloc%=Intin+4
  613.   Do
  614.     Char%=Peek(Loc%+Kount%)
  615.     Dpoke Stringloc%+(Kount%*2),Char%
  616.     Inc Kount%
  617.     Exit If Char%=0
  618.   Loop
  619.   Dpoke Contrl+6,Kount%+2
  620.   Dpoke Contrl+10,10
  621.   Dpoke Contrl+12,Handle%
  622.   Dpoke Intin,Word%
  623.   Dpoke Intin+2,Char%
  624.   Vdisys 11
  625. Return
  626. '
  627. Procedure Drawtext(Handle%,X%,Y%,Loc%)
  628.   '
  629.   ' Prints text at coordinates X%, Y%.
  630.   '
  631.   ' Loc% points to the text string.
  632.   '
  633.   Dpoke Contrl+2,1
  634.   Dpoke Ptsin,X%
  635.   Dpoke Ptsin+2,Y%
  636.   Kount%=0
  637.   Do
  638.     Char%=Peek(Loc%+Kount%)
  639.     Dpoke Intin+(Kount%*2),Char%
  640.     Inc Kount%
  641.     Exit If Char%=0
  642.   Loop
  643.   Dpoke Contrl+6,Kount%
  644.   Dpoke Contrl+12,Handle%
  645.   Vdisys 8
  646. Return
  647. '
  648.